Halcon基于形状匹配的人脸追踪编程分享

Halcon基于形状匹配的人脸追踪

*打开摄像头句柄AcqHandle

open_framegrabber ('DirectShow', 1, 1, 0, 0, 0, 0, 'default', 8, 'rgb', -1, 'false', 'default', '[0] USB2.0 HD UVC WebCam', 0, -1, AcqHandle)

*从摄像头抓取一张图片

grab_image (Image, AcqHandle)

*抓完关闭摄像头

close_framegrabber (AcqHandle)

dev_close_window ()

get_image_size (Image, Width, Height)

dev_open_window (0, 0, Width, Height, 'black', WindowHandle)

*打开一个窗口，尺寸400*400，黑色背景，句柄赋予WindowHandle

dev_set_draw ('margin')

*'margin'只显示轮廓，'fille'显示填充

dev_display (Image)

*定义数组显示提示信息

Message[0] := ' 提 示：'

Message[1] := '右键画面开始创建识别区域，按左键结束'

*显示数组中的提示信息

disp_message (WindowHandle, Message[0], 'window', 12, 12, 'red', 'true')

disp_message (WindowHandle, Message[1], 'window', 48, 12, 'black', 'true')

*继续提示语显示

disp_continue_message (WindowHandle, 'black', 'true')

draw_rectangle1 (WindowHandle, Row1, Column1, Row2, Column2)

*鼠标在打开的窗口绘制一个矩形，输出左上右下点的坐标

gen_rectangle1 (Rectangle, Row1, Column1, Row2, Column2)

*得到一个矩形

reduce_domain (Image, Rectangle, ImageReduced)

*缩小图像的域,取image与rectangle的交集，句柄ImageReduced，诣在从原图上扣取画出的区域

*执行断点处

stop()

*准备一个可变形模型，用于平面标定匹配轮廓。

*create_planar_uncalib_deformable_model (ImageReduced, 'auto', [], [], 'auto', 1, [], 'auto', 1, [], 'auto', 'none', 'use_polarity', 'auto', 'auto', [], [], ModelID)

create_planar_uncalib_deformable_model (ImageReduced, 5, rad(0), rad(360), rad(1), 1, 1, 0.02, 1, 1, 0.02, 'none', 'use_polarity', [42,57], 10, [], [], ModelID)

*create_planar_calib_deformable_model_xld（Template：：NumLevel，AngleStart，AngleExtent，AngleStep，ScaleRMin，ScaleRMax，ScaleRStep，ScaleCMin，ScaleCMax，ScaleCStep,Optimization,Metric,Contrast,MinContrast，GenParamName，GenParamValue：ModelID

*template输入模板

*NumLevels 输入金字塔最大层数（‘auto’（默认）, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10）

*AngleStart 在最小的旋转模式（-3.14, -1.57, -0.79, -0.39（默认）, -0.20, 0.0），

*AngleExtent 在旋转的角（6.29, 3.14, 1.57, 0.79（默认）, 0.39（输入条件：大于等于0））

*AngleStep 输入角度的步长（分辨率）（‘auto’（默认）, 0.0175, 0.0349, 0.0524, 0.0698, 0.0873，（输入条件：(AngleStep > 0) && (AngleStep <= (pi / 16))））

*ScaleRMin行方向上的图案的最小尺度（ 0.5, 0.6, 0.7, 0.8, 0.9, 1.0（默认）（输入条件：ScaleRMin > 0））

*ScaleRMax 在行方向上的图案的最大尺度（1.0（默认）, 1.1, 1.2, 1.3, 1.4, 1.5（输入条件：ScaleRMax >= ScaleRMin））

*ScaleRStep 在行方向上的刻度步长（分辨率）(‘auto’(默认), 0.01, 0.02, 0.05, 0.1, 0.15, 0.2，（输入条件：ScaleCStep > 0）)

*ScaleCMin 行方向上的图案的最小尺度（ 0.5, 0.6, 0.7, 0.8, 0.9, 1.0（默认）（输入条件：ScaleRMin > 0））

*ScaleCStep 在列方向上的刻度步长（分辨率）(‘auto’(默认), 0.01, 0.02, 0.05, 0.1, 0.15, 0.2，（输入条件：ScaleCStep > 0）)

*Optimization 一种用于生成模型的优化方法（ ‘auto’（默认）, ‘none’, ‘point_reduction_low’, ‘point_reduction_medium’, ‘point_reduction_high’）

*Metric （ ‘use_polarity’, ‘ignore_global_polarity’, ‘ignore_part_polarity’, ‘ignore_local_polarity’,‘ignore_color_polarity’（默认））

*Contrast 搜索图像中物体的对比度

*MinContrast 搜索图像中物体的最小对比度（1, 2, 3, 5（默认）, 7, 10, 20, 30, 40）

*GenParamName 泛型参数名（[],‘part_size’）

*GenParamValue 泛型参数的值（ [], ‘small’, ‘medium’, ‘big’）

*ModelID 模型的句柄

get_deformable_model_contours (ModelContours, ModelID, 1)

*返回可变形模型的轮廓表示，输出：输入模板轮廓，级别1、2、3、4、5、6、7、8、9、10（Level >= 1）

*测量输入轮廓的面积与中心值

area_center (Rectangle, ModelRegionArea, RefRow, RefColumn)

*仿射变换

vector_angle_to_rigid (0, 0, 0, RefRow, RefColumn, 0, HomMat2D)

*对XLD轮廓进行任意仿射2D变换

affine_trans_contour_xld (ModelContours, TransContours, HomMat2D)

dev_set_color ('green')

dev_set_draw ('margin')

dev_display (Image)

dev_display (Rectangle)

dev_display (TransContours)

stop ()

open_framegrabber ('DirectShow', 1, 1, 0, 0, 0, 0, 'default', 8, 'rgb', -1, 'false', 'default', '[0] USB2.0 HD UVC WebCam', 0, -1, AcqHandle)

while (true)

grab_image (Image, AcqHandle)

find_planar_uncalib_deformable_model (Image, ModelID, rad(0), rad(360), 1, 1, 1, 1, 0.5, 0, 0.5, 5, 0.75, ['subpixel'], ['least_squares_very_high'], ResultHomMat2D, Score)

dev_display (Image)

for I := 0 to |Score| - 1 by 1

TempHomMat2D := ResultHomMat2D[I*9:I*9+8]

projective_trans_contour_xld (ModelContours, TransContours, TempHomMat2D)

*       将射影变换应用于 XLD 轮廓

dev_set_color ('green')

* dev_display (TransContours)

*xld转换成region

gen_region_contour_xld (TransContours, Region, 'filled')

union1 (Region, RegionUnion)

*对区域，生成最小外接矩形

smallest_rectangle1 (RegionUnion, Row1, Column1, Row2, Column2)

*使用绿色矩形框，框选匹配结果

* dev_set_color ('green')

disp_rectangle1 (WindowHandle, Row1, Column1, Row2, Column2)

*使用红色勾画匹配结果轮廓

*        stop ()

endfor

endwhile

编辑：黄飞