ESP32学习笔记：WiFi

今天我们来说说ESP32 的WiFi。

ESP32的WiFi

我们之所以使用ESP32做一些小项目，最重要的就是看中了ESP32的WiFi功能，ESP32相当于一个强大的单片机+无线WiFi+蓝牙多合一的一个芯片，芯片有了WiFi，它就不再孤独寂寞，就可以与外界通信，这就是它区别于常规MCU最大的特点，就像2G手机跟4G手机的区别，4G手机能实现很多2G手机时代渴望的功能。

WiFi就是一种无线通讯技术，生活中接触最多的就是电脑跟手机通过路由器的WiFi信号上网，说白了其实就是一种射频信号，跟我们早期接触的315MHz、433MHz射频通信，蓝牙，Zigbee等一样，WiFi工作于2.4GHz或者5Ghz的频率，今天我们先学习一下WiFi的基本功能。

AP模式

AP模式就是让ESP32建立一个网络，可以发出WiFi信号来让其他设备搜索到，就跟路由器发出信号来类似，只需要一行代码，我们就可以建立一个我们自己命名的无线网络了，期待一下。

#include < WiFi.h >

void setup(){
  WiFi.softAP("ESP32_WiFi");
}

void loop(){
}

上面这一行代码，我们就建立了一个名为ESP32_WiFi的，不加密的无线网络了，我们将代码烧录进去，然后打开手机WiFi连接界面，就可以看到这个网络并进行连接了。

常用函数

我们打开WiFiAP.h这个头文件就可以看到AP模式的相关函数了，这里分享一些常用的，有一些概念比如子网掩码，网关地址等不清楚的，大家可以自行上网查看。

该函数建立并启动AP网络

bool softAP(const char* ssid, const char* passphrase = NULL, int channel = 1, int ssid_hidden = 0, int max_connection = 4);

• ssid，AP网络的名字，最大不超过32字节；
• passphrase，密码，8-63字节，不设置就是不加密；
• channel，WiFi网络信道，1-13可选；
• ssid_hidden，网络名字是否隐藏；
• ssid_hidden，最大接入数，1-4可选。

本地地址等设置

bool softAPConfig(IPAddress local_ip, IPAddress gateway, IPAddress subnet);

• local_ip，本地网络地址，比如默认为192.168.4.1；
• gateway，网关地址， 192.168.4.1；
• subnet，子网掩码，255.255.255.0。

连接数量，返回连接到本AP的客户端的数量

uint8_t softAPgetStationNum();

设置主机名字，比如设置为"CHIPHOME"

bool softAPsetHostname(const char * hostname);

查询主机的MAC地址，函数返回主机的MAC地址

String softAPmacAddress(void);

代码测试

下面我们写一个小程序，测试下上面几个函数的功能：

#include < WiFi.h >

const char *ssid = "ESP32_WiFi";
const char *password = "12345678";

IPAddress local_IP(192,168,4,1);
IPAddress gateway(192,168,4,1);
IPAddress subnet(255,255,255,0);

void setup(){
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_AP); // AP模式

  WiFi.softAPConfig(local_IP, gateway, subnet); // 设置AP地址
  WiFi.softAP(ssid, password);                  // 启动AP成功返回1

  Serial.print("IP address: ");
  Serial.println(WiFi.softAPIP()); // 打印IP地址

  WiFi.softAPsetHostname("CHIPHOME"); // 设置主机名
  Serial.print("Hostname: ");
  Serial.println(WiFi.softAPgetHostname()); // 打印主机名

  Serial.print("MAC Address: ");
  Serial.println(WiFi.softAPmacAddress()); // 打印MAC地址  
}

void loop(){ 
  Serial.print("当前连接客户端数: ");
  Serial.println(WiFi.softAPgetStationNum()); // 打印客户端连接数量
  delay(5000);
}

将上面代码编译烧录之后，我们可以在串口监视器中看到如下打印：

代码中如预期的打印了了IP地址，主机名，MAC地址，连接数量，OK，AP模式相关我们就介绍到这里。

STA模式

STA模式就是让ESP32当做客户端，去连接AP主机，就好比手机去连接路由器一样。

#include < WiFi.h >

const char *ssid = "********"; // 网络名称
const char *password = "********"; // 网络密码

void setup(){
 WiFi.begin(ssid, password);
}

void loop(){
}

上面这一行代码，我们就将ESP32设置为STA模式，ssid跟password填写我们要连接的WiFi的账号密码，就可以连接上了。

常用函数

我们打开WiFiSTA.h这个头文件就可以看到STA模式的相关函数了，全部的请查阅SDK，下面是一些常用的一些：

该函数用于接入WiFi网络，参数同上面的AP模式基本一样，一般就设置第一个跟第二个参数，其他选择默认

wl_status_t begin(const char* ssid, const char *passphrase = NULL, int32_t channel = 0, const uint8_t* bssid = NULL, bool connect = true);
wl_status_t begin(char* ssid, char *passphrase = NULL, int32_t channel = 0, const uint8_t* bssid = NULL, bool connect = true);

设置网络地址，包括本机IP，网关地址，子网掩码，DNS

bool config(IPAddress local_ip, IPAddress gateway, IPAddress subnet, IPAddress dns1 = (uint32_t)0x00000000, IPAddress dns2 = (uint32_t)0x00000000);

联网状态

static wl_status_t status();

返回不同的枚举值代表不同的状态：

• 0：WL_IDLE_STATUS正在WiFi工作模式间切换；
• 1：WL_NO_SSID_AVAIL无法访问设置的SSID网络；
• 2：WL_SCAN_COMPLETED扫描完成；
• 3：WL_CONNECTED连接成功；
• 4：WL_CONNECT_FAILED连接失败；
• 5：WL_CONNECTION_LOST丢失连接；
• 6：WL_DISCONNECTED断开连接；

模块IP地址

IPAddress localIP()

模块子网掩码

IPAddress subnetMask()

模块网关地址

IPAddress gatewayIP()

模块MAC地址

const char * getHostname()

代码测试

下面我们写一个小程序，测试下上面几个函数的功能：

#include < WiFi.h >

const char *ssid = "*********";  //改为你自己的WIFI账号
const char *password = "********"; //改为你自己的WIFI密码

void setup(){
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA); //设置工作在STA模式

  WiFi.begin(ssid, password); //连接WiFi

  while (WiFi.status() != WL_CONNECTED ){  //等待网络连接成功
    delay(1000);
    Serial.print(".");
  }
  Serial.println("WiFi Connected!");

  Serial.print("IP address: ");
  Serial.println(WiFi.localIP()); //IP地址

  Serial.print("subnetMask: ");
  Serial.println(WiFi.subnetMask()); //子网掩码地址

  Serial.print("gateway: ");
  Serial.println(WiFi.gatewayIP()); //网关地址

  Serial.print("MAC Address: ");
  Serial.println(WiFi.macAddress()); //MAC地址
}

void loop(){
}

将上面代码编译烧录之后，我们可以在串口监视器中看到如下打印：

代码中如预期的打印了了IP地址，子网掩码，网关地址，MAC地址，既然ESP32连接上路由器了，那么我们在路由器的设备列表页面是不是也能看到ESP32：

异步搜索

有一些情况，我们需要知道当前空间中存在哪些WiFi信号，比如在WiFi配网的时候，下面我们搜索一下当前空间中的WiFi信息，然后打印出来。

常用函数

我们打开WiFiScan.h这个头文件就可以看到Scan的相关函数了，全部的请查阅SDK，下面是一些常用的一些：

该函数用于扫描启动

int16_t scanNetworks(bool async = false, bool show_hidden = false, bool passive = false, uint32_t max_ms_per_chan = 300, uint8_t channel = 0);

• async，异步扫描，设置为true则不阻塞；
• show_hidden，是否扫描不广播的网络；
• passive，扫描速度；
• max_ms_per_chan，每个通道的扫描时间；
• channel，通道选择。

该函数用于判断扫描是否完成

int16_t scanComplete();

• -1，扫描还没结束；
• -2，扫描还没触发；
• n，扫描到的WiFi信号个数；

删除内存中的扫描数据

void scanDelete();

扫描到的网络名称

String SSID(uint8_t networkItem);

扫描到的网络加密类型

wifi_auth_mode_t encryptionType(uint8_t networkItem)

扫描到的网络信号强度

int32_t RSSI(uint8_t networkItem)

扫描到的网络信道号

int32_t channel(uint8_t networkItem)

代码测试

下面我们写一个小程序，异步扫描我们空间中当前存在的WiFi信号并打印出来：

#include < WiFi.h >

void setup(){
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA);  // 设置为STA模式

  Serial.println("开始扫描");
  WiFi.scanNetworks(true); //启动异步扫描
}

void loop(){  
  int n = WiFi.scanComplete(); //获取扫描状态,信号个数
  if (n >= 0){
    Serial.println("扫描完成");
    for (int i = 0; i < n; ++i){
      Serial.println();
      Serial.print(i + 1);
      Serial.print(":       ");
      Serial.print(WiFi.SSID(i)); //网络名称
      Serial.print("        ");
      Serial.print(WiFi.RSSI(i)); //信号强度
      Serial.print("        ");
      Serial.print((WiFi.encryptionType(i) == WIFI_AUTH_OPEN) ? "未加密" : "加密"); //是否加密
      delay(10);
    }
    WiFi.scanDelete(); //清除内存中的扫描结果
  }
  else if (n == -1){
    Serial.println("正在扫描");
  }
  else if (n == -2) {
    Serial.println("未触发扫描");
  }

  delay(1000);
}

我们看下打印的结果，周围的WiFi信号的数据都被打印了出来

到这里，WiFi的基本使用我们算是入门了，联网之后，外面的世界非常美妙，我们可以做很多有意思的项目，做一些漂亮的网络时钟，做一些智能家居的小产品，做一个网络收音机，做一个游戏模拟器，很多很多......

关于WiFi的一些其它功能，比如TCP协议，UDP协议，Web服务器等，我们用到的时候再细说。

感谢大家，关于ESP32的学习，希望大家Enjoy!