用Arduino读取MPU9250传感器

描述

主条目：使用 Arduino 读取 MPU9250 传感器

MPU-9250 是目前市场上最先进的加速度计、陀螺仪和指南针组合小尺寸传感器之一。它取代了流行的 MPU-9150，降低了功耗，改善了陀螺噪声和罗盘满量程性能。它具有许多高级功能，包括低通滤波、运动检测甚至可编程专用处理器。

它内部包括 MPU-6500，其中包含一个 3 轴陀螺仪和一个 3 轴加速度计，以及AK8963 ，市场领先的 3 轴数字罗盘。MPU-9250 使用 16 位模数转换器 (ADC) 对所有 9 个轴进行数字化。

陀螺仪

陀螺仪是一种用于测量或保持方向和角速度的设备。以每秒度数（或弧度）为单位测量的角速度是单位时间内物体旋转角度的变化。

根据方向的不同，角速率测量分为三种类型：

• 偏航：从上方看物体时在平面上的水平旋转。

• 俯仰：从正面看物体时的垂直旋转。

• 滚动：从前面看物体时水平旋转。

加速度计

加速度计传感器是测量加速度的集成电路 (IC)，加速度是每单位时间的速度变化。测量加速度可以获取物体倾斜度和振动等信息。

通常，g用作加速度的单位，相对于标准重力 (1g = 9.80665m/s2)。

磁力计

磁力计提供有关设备传感器检测到的磁场的信息，理论上可以暴露用户的位置。磁力计传感器测量所有三个物理轴（x、y、z）的磁场，单位为 μT（微特斯拉）。

绝对方向传感器是磁力计的常见用例之一，它代表地球平面的固定方向（固定到磁场矢量和重力矢量）。

接线图

基本使用连接电源引脚和SDA 、SCL引脚，如下图所示：

Arduino Nano 接线与 MPU9250

 

解释数据

我们的官方存储库中有官方 MPU9250 数据表和寄存器图。它描述了 MPU-9250 中每个寄存器的功能和内容，包括磁力计。我们建议您阅读十进制、二进制和十六进制表示的帖子，以轻松识别寄存器并理解其中内容的含义。

 

寄存器映射的前两列表示十六进制和十进制格式的地址，后跟寄存器名称。一些寄存器是只读的（用 R 标记），而另一些则允许我们写（用 R/W 标记）。寄存器的内容用 8 位表示。在各种情况下，寄存器的值可能代表不止一个东西，换句话说，每个位或位组可能具有不同的含义，例如GYRO_CONFIG（寄存器27）。

MPU-9250 的每个传感器都具有 16 位精度。这意味着使用两个 8 位寄存器来表示输出。我们将从每个寄存器中分别读取 8 位数据，然后将它们连接起来形成 16 位。

为 I2C 安装 Arduino 库

我们将使用 I2C 协议与寄存器交互并读/写数据。I2C 库为此目的提供了一个非常简单的接口，并且可以在使用 I2C 协议的其他项目中重用。它可以从我们的官方存储库中下载。

要导入库，请打开 Arduino IDE，转到 Sketch > Include Library > Add.ZIP Library，然后选择从我们的 GitHub 存储库下载的库文件。

 

然后你可以简单地使用include语句：

#include "I2C.h"

它将包含具有与寄存器交互的预定义函数的库。

Arduino代码

我们为每个原始传感器数据定义了一个单独的结构：gyroscope_raw 、accelerometer_raw 、magnetometer_raw和temperature_raw 。每个原始结构都有一个基于当前配置的数据规范化函数。人类可读的标准化值存储在另一个名为normalized的结构中。

确保遵循上一步并导入 I2C 库，以便将其与include语句一起使用：

#include "Wire.h"
#include "I2C.h"

#define MPU9250_IMU_ADDRESS 0x68
#define MPU9250_MAG_ADDRESS 0x0C

#define GYRO_FULL_SCALE_250_DPS  0x00
#define GYRO_FULL_SCALE_500_DPS  0x08
#define GYRO_FULL_SCALE_1000_DPS 0x10
#define GYRO_FULL_SCALE_2000_DPS 0x18

#define ACC_FULL_SCALE_2G  0x00
#define ACC_FULL_SCALE_4G  0x08
#define ACC_FULL_SCALE_8G  0x10
#define ACC_FULL_SCALE_16G 0x18

#define TEMPERATURE_OFFSET 21 // As defined in documentation

#define INTERVAL_MS_PRINT 1000

#define G 9.80665

struct gyroscope_raw {
  int16_t x, y, z;
} gyroscope;

struct accelerometer_raw {
  int16_t x, y, z;
} accelerometer;

struct magnetometer_raw {
  int16_t x, y, z;

  struct {
    int8_t x, y, z;
  } adjustment;
} magnetometer;

struct temperature_raw {
  int16_t value;
} temperature;

struct {
  struct {
    float x, y, z;
  } accelerometer, gyroscope, magnetometer;

  float temperature;
} normalized;

unsigned long lastPrintMillis = 0;

void setup()
{
  Wire.begin();
  Serial.begin(115200);

  I2CwriteByte(MPU9250_IMU_ADDRESS, 27, GYRO_FULL_SCALE_1000_DPS); // Configure gyroscope range
  I2CwriteByte(MPU9250_IMU_ADDRESS, 28, ACC_FULL_SCALE_2G);        // Configure accelerometer range

  I2CwriteByte(MPU9250_IMU_ADDRESS, 55, 0x02); // Set by pass mode for the magnetometers
  I2CwriteByte(MPU9250_IMU_ADDRESS, 56, 0x01); // Enable interrupt pin for raw data

  setMagnetometerAdjustmentValues();

  //Start magnetometer
  I2CwriteByte(MPU9250_MAG_ADDRESS, 0x0A, 0x12); // Request continuous magnetometer measurements in 16 bits (mode 1)
}

void loop()
{
  unsigned long currentMillis = millis();

  if (isImuReady()) {
    readRawImu();

    normalize(gyroscope);
    normalize(accelerometer);
    normalize(temperature);
  }

  if (isMagnetometerReady()) {
    readRawMagnetometer();

    normalize(magnetometer);
  }

  if (currentMillis - lastPrintMillis > INTERVAL_MS_PRINT) {
    Serial.print("TEMP:\t");
    Serial.print(normalized.temperature, 2);
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.print("C");
    Serial.println();

    Serial.print("GYR (");
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.print("/s):\t");
    Serial.print(normalized.gyroscope.x, 3);
    Serial.print("\t\t");
    Serial.print(normalized.gyroscope.y, 3);
    Serial.print("\t\t");
    Serial.print(normalized.gyroscope.z, 3);
    Serial.println();

    Serial.print("ACC (m/s^2):\t");
    Serial.print(normalized.accelerometer.x, 3);
    Serial.print("\t\t");
    Serial.print(normalized.accelerometer.y, 3);
    Serial.print("\t\t");
    Serial.print(normalized.accelerometer.z, 3);
    Serial.println();

    Serial.print("MAG (");
    Serial.print("\xce\xbc"); //Print micro symbol
    Serial.print("T):\t");
    Serial.print(normalized.magnetometer.x, 3);
    Serial.print("\t\t");
    Serial.print(normalized.magnetometer.y, 3);
    Serial.print("\t\t");
    Serial.print(normalized.magnetometer.z, 3);
    Serial.println();

    Serial.println();

    lastPrintMillis = currentMillis;
  }
}

注意：该片段是位于我们的 GitHub存储库中的 Arduino 项目的一部分，代码分隔在不同的逻辑文件中。

测试

串行监视器将每隔INTERVAL_MS_PRINT毫秒打印最后一次可用的传感器数据（在上面的示例中，每秒一次），它应该类似于：

 

通常方向是在物理模块上绘制的，因此您可以轻松检测 X、Y 和 Z 轴。